SOURCE CODE – LIST
Pls note that we permit the distribution of this source code by CPC Retrodev and the University of Alicante.
We also mention this in line 10 (first) of the list.
Pls read first making of in order to better understand the philosophy of the game and this list.


1-140 MENU AND VARIABLES.
150-410 MAIN GAME
500-550 WIN GAME
800-844 HIGHSCORE
845-890 OTHER
900-930 REDEFINE KEYS
935-960 LANGUAGE CHANGE
970-973 PRINT LEVEL
1000-1095 LANGUAGE CHANGE
2000-2490 INSTRUCTIONS
2500-2990 HISTORY
3000-3199 INTRO 1
3200-3459 INTRO 2
3460-3490 INTRO 3
3500-3990 SOUND DESIGN
4000-4020 SECRET MENU OPTION
4100-4190 SELECT DIFFICULTY
4400-4450 GAME OVER
4500-4520 COUNTDOWN CLOCK
4700 -4730 LOSE QUESTION DUE TIME IS OVER
5000-9450 QUESTIONS 
9800-9890 DRAWING SHAPES
10000-10060 GREEK LANGUAGE
10100-10500 EXTRAS

ABOUT 5000-9450 QUESTIONS:
This part of the list is divided in 9 categories.Each category starts every 500 (eg 5000,5500,6000, etc).
The programme decides randomly in which category of these 9 to go. Each category has a question for every Test. So, each category has 6 <chapters> (every 50). For example,the six chapters of 1st category are in 5050,5100,5150,5200,5250,5300. In the 2nd category six chapters are 5550,5600,5650,5700,5750,5800, etc.
So, to sum up, the random choice is based on the <which category the programme will lead to>. After that, there is a question for every test in each category.




10 REM COPYRIGHT BY SAKIS KAFFESAKIS 2020. WE PERMIT THE DISTRIBUTION OF THIS SOURCE CODE BY CPC RETRODEV AND THE UNIVERSITY OF ALICANTE
11 GOSUB 940:GOSUB 935:GOSUB 945:GOSUB 10000
12 MODE 1:INK 0,0:BORDER 11:INK 1,24:PEN 1:LOCATE 9,12:PRINT"PRESS SPACE FOR INTRO":LOCATE 9,14:PRINT"PRESS ANY KEY FOR GAME"
13 Q$=INKEY$
14 IF Q$=" " THEN GOTO 17
15 IF Q$<>"" THEN GOTO 18
16 GOTO 13
17 GOSUB 3000
18 GOSUB 3820:REM SOUND
19 GOSUB 940:GOSUB 935:GOSUB 945:GOSUB 10000
20 CLS:MODE 1:BORDER 11:PEN 3:INK 3,20:INK 0,0:RANDOMIZE TIME   
30 LOCATE 7,2:PRINT "Welcome to..." 
50 FOR delay=1 TO 100:NEXT delay:LOCATE 15,7:PEN 2:SPEED INK 40,40:INK 2,19,24:PRINT "STROOPIE!!!" 
60 PEN 1:INK 1,15:LOCATE 13,11:PRINT"1. START GAME":LOCATE 13,13:PRINT"2. INSTRUCTIONS":LOCATE 13,15:PRINT"3. HISTORY":LOCATE 13,17:PRINT"4. REDEFINE KEYS":LOCATE 13,19:PRINT"5. LANGUAGE"
70 LOCATE 8,22:PEN 3:PRINT"by SAKIS KAFFESAKIS":LOCATE 28,22:PRINT CHR$(164):LOCATE 30,22:PRINT"2020":LOCATE 7,24:PRINT"www.amstradsakis.blogspot.com":MOVE 90,15:DRAW 565,15 
75 GOSUB 850
80 A$=INKEY$
90 IF A$="2" THEN GOSUB 2000:GOTO 20
100 IF A$="3" THEN GOSUB 2500:GOTO 20
110 IF A$="1" THEN GOTO 130
115 IF A$="4" THEN GOSUB 900:GOTO 20
117 IF A$="5" THEN GOSUB 1000:GOTO 20
119 IF A$="0" THEN GOSUB 4000:GOTO 20
120 GOTO 80
130 CLS:PEN 1:INK 1,15:LOCATE 10,10:INPUT"NAME OF PLAYER 1? ",OFI$:OFI$=LEFT$(OFI$,10) 
135 GOSUB 4100
136 DTIM=8.1-DIF
140 CLS
150 REM START GAME
160 SCORE=0:L=3:AFT=0:ELIXE=0:IF CODE=1 THEN L=500
162 PEN 1:INK 1,24:PEN 2:INK 2,19:PEN 3:INK 3,6:PEN 1
165 MODE 1:INK 0,0
167 FOR LEV=1 TO 3
169 FOR KEF=1 TO 6
170 IF KEF=1 THEN GOSUB 970
171 IF LEV=3 AND KEF=6 THEN L=L+1
172 FOR EROT=1 TO 10
173 GOSUB 850
174 PEN 3:INK 3,26:CLS:LOCATE 27,1:PRINT"LIVES:";L:LOCATE 27,3:PRINT"SCORE:";SCORE
175 LOCATE 1,1:PRINT"LEVEL:";LEV;"/"KEF;"/"EROT
180 TYX=INT(RND*9)+1:TYX=INT(RND*9)+1
190 ON TYX GOSUB 5000,5500,6000,6500,7000,7500,8000,8500,9000
195 AFT=0:TIM=DTIM-LEV:EVERY 5,2 GOSUB 4500:AFTER (TIM-0.1)*50,1 GOSUB 4700 
197 APA=0:ELIXE=0
199 IF LEV=3 AND KEF=6 AND EROT=1 THEN GOSUB 10100
200 AN$=INKEY$
205 IF AFT=1 THEN GOTO 250
210 IF AN$=PA$ THEN APA=1:GOTO 250
220 IF AN$=PB$ THEN APA=2:GOTO 250
230 IF AN$=PC$ THEN APA=3:GOTO 250
240 IF AN$<>PA$ AND AN$<>PB$ AND AN$<>PC$ THEN GOTO 200
250 IF APA<>COR THEN L=L-1 
252 IF DIF=1 THEN DIFSC=DIF*1
254 IF DIF=2 THEN DIFSC=DIF*1.2
256 IF DIF=3 THEN DIFSC=DIF*1.4
258 IF DIF=4 THEN DIFSC=DIF*2.2
260 WTP=REMAIN(2):BON=REMAIN(1)*DIFSC*LEV:BON=ROUND(BON,0)
265 PEN 3:IF APA=COR THEN LOCATE 15,23:PRINT"  CORRECT!  ":GOSUB 3600 ELSE LOCATE 15,23:PRINT "   WRONG!   ":GOSUB 3700
270 IF APA=COR THEN LOCATE 30,23:PRINT "+";BON:SCORE=SCORE+BON:LOCATE 27,3:PRINT"SCORE:";SCORE;"   "
280 LOCATE 27,1:PRINT"LIVES:";L;"  " 
295 FOR DELAY=1 TO 700:NEXT DELAY
297 IF L<=0 THEN GOTO 4400
300 NEXT EROT
330 NEXT KEF
400 NEXT LEV
410 GOSUB 500:GOTO 4400
500 REM WIN GAME
505 GOSUB 850
507 PEN 1:INK 1,19
510 CLS:MODE 1:LOCATE 15,10:GOSUB 3650:PRINT"YOU WIN!!!":LOCATE 14,12:PRINT"SCORE:";SCORE
515 PEN 2:INK 2,24
520 IF DIF=1 THEN LOCATE 7,16:PRINT"YOU UNLOCKED THE 1ST LETTER":LOCATE 6,18:PRINT"OF THE PASSWORD FOR 500 LIVES:":LOCATE 17,20:PRINT" < O >" 
521 IF DIF=2 THEN LOCATE 6,16:PRINT"YOU UNLOCKED THE 1ST TWO LETTERS":LOCATE 6,18:PRINT"OF THE PASSWORD FOR 500 LIVES:":LOCATE 17,20:PRINT" < OF >"
522 IF DIF=3 THEN LOCATE 8,16:PRINT"YOU UNLOCKED ALL LETTERS":LOCATE 6,18:PRINT"OF THE PASSWORD FOR 500 LIVES:":LOCATE 16,20:PRINT" < OFI >"
523 IF DIF=4 THEN LOCATE 8,16:PEN 3:INK 3,6:PRINT"YOU HAVE BEATEN THIS GAME!":PEN 2:LOCATE 9,18:PRINT"PASSWORD FOR 500 LIVES:":LOCATE 16,20:PRINT" < OFI >":LOCATE 6,22:PRINT"PRESS 0 IN THE MENU TO ENTER IT"
525 PEN 1
530 LOCATE 14,24:PRINT"PRESS ANY KEY"
535 T$=INKEY$
536 IF T$<>"" THEN RETURN
537 GOTO 535
550 RETURN
800 REM HIGHSCORE
801 LA$="SAKIS":LB$="JORGE":LC$="TIMBAULT":LD$="KARL":LA=175000:LB=130000:LC=100000:LD=60000
802 MODE 1:GOSUB 3850
805 IF SCORE>=LA THEN SA$=OFI$:SB$=LA$:SC$=LB$:SD$=LC$:SE$=LD$:SA=SCORE:SB=LA:SC=LB:SD=LC:SE=LD
806 IF SCORE<LD THEN SA$=LA$:SB$=LB$:SC$=LC$:SD$=LD$:SE$=OFI$:SA=LA:SB=LB:SC=LC:SD=LD:SE=SCORE
807 IF SCORE<LA AND SCORE>=LB THEN SA$=LA$:SB$=OFI$:SC$=LB$:SD$=LC$:SE$=LD$:SA=LA:SB=SCORE:SC=LB:SD=LC:SE=LD
808 IF SCORE<LB AND SCORE>=LC THEN SA$=LA$:SB$=LB$:SC$=OFI$:SD$=LC$:SE$=LD$:SA=LA:SB=LB:SC=SCORE:SD=LC:SE=LD
809 IF SCORE<LC AND SCORE>=LD THEN SA$=LA$:SB$=LB$:SC$=LC$:SD$=OFI$:SE$=LD$:SA=LA:SB=LB:SC=LC:SD=SCORE:SE=LD 
810 GOSUB 850
815 PEN 1:INK 1,6,19:LOCATE 16,4:PRINT"HIGHSCORE"
816 PEN 2:INK 2,24:LOCATE 10,7:PRINT SA$:LOCATE 10,9:PRINT SB$:LOCATE 10,11:PRINT SC$:LOCATE 10,13:PRINT SD$:LOCATE 10,15:PRINT SE$
817 LOCATE 25,7:PRINT SA:LOCATE 25,9:PRINT SB:LOCATE 25,11:PRINT SC:LOCATE 25,13:PRINT SD:LOCATE 25,15:PRINT SE
820 PEN 1:INK 1,19
844 RETURN
845 REM PRESS ANY KEY
846 F$=INKEY$
847 IF F$<>"" THEN RETURN
848 GOTO 846
850 WA$=INKEY$:WB$=INKEY$:WC$=INKEY$:WD$=INKEY$:WE$=INKEY$:RETURN
890 PEN 1::END
900 REM REDEFINE
901 CLS
902 MODE 2:PEN 1:INK 1,24:LOCATE 7,2:PRINT"DEFAULT KEYS ARE:":LOCATE 7,4:PRINT "a FOR ANSWER 1 (ON THE LEFT)":LOCATE 7,6:PRINT"w FOR ANSWER 2 (IN THE CENTRE)":LOCATE 7,8:PRINT"d FOR ANSWER 3 (ON THE RIGHT)"
903 LOCATE 7,10:PRINT"DEFAULT KEYS ARE NOT CAPITAL LETTERS"
904 LOCATE 7,12:PRINT"FOR OTHER LANGUAGE KEYBOARDS PLS REDEFINE AS <w> MAY NOT WORK PROPERLY" 
905 GOSUB 850:LOCATE 7,15:PRINT"PRESS 1 TO ENTER NEW KEYS OR SPACE TO CANCEL"
906 R$=INKEY$
907 IF R$=" " THEN RETURN
908 IF R$="1" THEN GOTO 918
909 GOTO 906
918 PA$="":PB$="":PC$=""
920 LOCATE 7,18:INPUT"PLS PRESS KEY FOR ANSWER 1";PA$
921 IF LEN(PA$)>1 OR LEN(PA$)<1 THEN PA$="a":LOCATE 7,18:PRINT SPC(40):GOTO 920
923 LOCATE 7,20:INPUT"PLS PRESS KEY FOR ANSWER 2";PB$
924 IF LEN(PB$)>1 OR LEN(PB$)<1 OR PB$=PA$ THEN PB$="w":LOCATE 7,20:PRINT SPC(40):GOTO 923
926 LOCATE 7,22:INPUT"PLS PRESS KEY FOR ANSWER 3";PC$
927 IF LEN(PC$)>1 OR LEN(PC$)<1 OR PC$=PA$ OR PC$=PB$ THEN PC$="d":LOCATE 7,22:PRINT SPC(40):GOTO 926
928 GOSUB 3560:LOCATE 7,24:PRINT"PLS DONT PRESS CAPSLOCK KEY FROM NOW ON"
929 GOSUB 845
930 RETURN
935 REM DEFAULT
936 L=2:DIF=2:DTIM=6.1:GL=1
939 RETURN
940 PA$="a":PB$="w":PC$="d"
941 YE$="YELLOW":RE$="RED":GR$="GREEN"
942 TE$="SQUARE":TR$="TRIANGLE":PE$="TRAPEZIUM"
943 RETURN
945 REM GLOSSES
946 IF GL=2 THEN YE$=KI$:RE$=KO$:GR$=PR$:TE$=GO$:TR$=NO$:PE$=ZI$
948 IF GL=3 THEN YE$="AMARILLO":RE$="ROJO":GR$="VERDE":TE$="CUADRADO":TR$="TRIANGULO":PE$="TRAPECIO"
950 IF GL=4 THEN YE$="JAUNE":RE$="ROUGE":GR$="VERT":TE$="CARRE":TR$="TRIANGLE":PE$="TRAPEZE"
952 IF GL=1 THEN YE$="YELLOW":RE$="RED":GR$="GREEN":TE$="SQUARE":TR$="TRIANGLE":PE$="TRAPEZIUM"
954 IF GL=5 THEN YE$="GELB"::RE$="ROT":GR$="GRUN":TE$="QUADRAT":TR$="DREIECK":PE$="TRAPEZ"
955 RETURN
956 IF GL=0 THEN GOTO 960
957 YE$="AMARILLO":RE$="ROJO":GR$="VERDE":TE$="CUADRADO":TR$="TRIANGULO":PE$="TRAPECIO"
960 RETURN
970 CLS:MODE 1:LOCATE 17,12:PEN 3:INK 3,26:PRINT"LEVEL";LEV
971 Z$=INKEY$
972 IF Z$<>"" THEN :GOSUB 850:RETURN
973 GOTO 971
1000 REM GLOSSES ARXIKO
1010 CLS:MODE 2:PEN 1:INK 1,24:LOCATE 12,7:PRINT"SELECT LANGUAGE":LOCATE 17,10:PRINT"1. ENGLISH":LOCATE 17,12:PRINT "2. GREEK":LOCATE 17,14:PRINT"3. SPANISH":LOCATE 17,16:PRINT "4. FRENCH":LOCATE 17,18:PRINT "5. GERMAN"
1015 LOCATE 12,21:PRINT"LANGUAGE CHANGE AFFECTS ONLY THE WORDS OF COLOURS AND SHAPES"
1017 GOSUB 850
1020 G$=INKEY$
1025 IF G$="1" THEN GL=1:GOTO 1090
1026 IF G$="2" THEN GL=2:GOTO 1090
1027 IF G$="3" THEN GL=3:GOTO 1090
1028 IF G$="4" THEN GL=4:GOTO 1090
1030 IF G$="5" THEN GL=5:GOTO 1090
1040 GOTO 1020
1090 GOSUB 3560:GOSUB 945
1095 RETURN
2000 REM INSTRUCTIONS
2010 MODE 2:PEN 1:INK 1,24
2020 LOCATE 1,1:PRINT"This game consists of 3 levels.":LOCATE 1,3:PRINT "Each level consists of 6 different tests, and each test of 10 questions."
2030 LOCATE 1,5:PRINT"On each question, you have to select between 3 answers and find the correct one":LOCATE 1,6:PRINT"in the limited time."
2040 LOCATE 1,9:PRINT"TEST 1:Find the colour displayed on the word (word has a neutral form <XXXXX>)."
2050 LOCATE 1,11:PRINT"TEST 2:Same with TEST 1, but the word's meaning tries to confuse you."
2060 LOCATE 1,13:PRINT "TEST 3:Find the shape displayed on the screen."
2070 LOCATE 1,15:PRINT "TEST 4:Same with TEST 3, but the word inside the shape tries to confuse you."
2080 LOCATE 1,17:PRINT"TEST 5:Find the correct combination of colour and shape shown in the screen."
2090 LOCATE 1,19:PRINT"TEST 6:Same with TEST 5, but the words inside the shape try to confuse you."
2100 LOCATE 1,22:PRINT"There are 3 colours and 3 shapes used in this game.":LOCATE 1,24:PRINT "Colours: green, yellow and red. Shapes: square, triangle and trapezium."
2105 GOSUB 850
2110 q$=INKEY$
2112 IF Q$<>"" THEN GOTO 2120
2115 GOTO 2110
2120 CLS
2130 LOCATE 1,1:PRINT"The difficulty level that you choose affects only the time limit."
2140 LOCATE 1,3:PRINT"Initial time available in easy mode is 6 sec, and in hardest mode it is 3 sec."
2150 LOCATE 1,5:PRINT"But:in each level you go through, time available is limited by 1 second."
2160 LOCATE 1,7:PRINT"There is no other effect of the level. In LEVEL 3 TEST 6 you gain 1 extra life.""
2170 LOCATE 1,9:PRINT"The sequence of the questions is totally random."
2180 LOCATE 1,11:PRINT"Points gained depend on remaining time for answering the question.": LOCATE 1,13:PRINT"Difficulty and level are also calculated.":LOCATE 1,15:PRINT"Most points are gained on first levels, so try to be quick."
2190 LOCATE 1,18:PRINT"If uou win a game, some letters of the SECRET CODE will be shown to you."
2200 LOCATE 1,20:PRINT"What is revealed (letters or where to enter them) is based on difficulty level."
2210 LOCATE 1,22:PRINT"There is a secret place somewhere in the menu."
2220 LOCATE 1,24:PRINT"By entering the secret code, you get 500 lives!"
2225 GOSUB 850
2230 q$=INKEY$
2235 IF Q$<>"" THEN GOTO 2490
2240 GOTO 2230
2490 RETURN
2500 REM HISTORY
2505 CLS:MODE 2:PEN 1:INK 1,24
2510 LOCATE 1,1:PRINT"The idea of this game is based on the Stroop effect and other similar experi-":LOCATE 1,2:PRINT"ments in the field of the perception psychology."
2520 LOCATE 1,4:PRINT"It seems that some cognitive processes (as reading) are so automatic that it is":LOCATE 1,5:PRINT"difficult to reduce them without training, even if we don't want them to occur."
2530 LOCATE 1,7:PRINT"The idea for making a game based on the Stroop effect came from my studies in ":LOCATE 1,8:PRINT"the psychology department of university of Crete, many years ago."
2540 LOCATE 1,10:PRINT"As this effect occurs mostly in the language you are most familiar with (native":LOCATE 1,11:PRINT"language), I decided to make the game available in many languages, so that it"
2550 LOCATE 1,12:PRINT"is easy for most people to play in the correct way."
2560 LOCATE 1,15:PRINT"HAVE FUN!!!"
2570 GOSUB 850
2580 GOSUB 845
2840 RETURN
2990 RETURN
3000 REM INTRO
3010 BORDER 11:INK 0,0:CLS:MODE 2:PEN 1:INK 1,24
3020 LOCATE 1,1:PRINT"This game is based on the <Stroop effect>,in the field of perception psychology."
3030 LOCATE 1,3:PRINT"In this intro, we present you, from the same scientific field, three optical":LOCATE 1,4:PRINT"illusions."
3040 LOCATE 1,7:PRINT"1: Muller - Lyer illusion"
3050 LOCATE 1,10:PRINT"At first, you will see 2 lines that are of the same length."
3060 LOCATE 1,12:PRINT"But when we add some more lines, these lines seem no more of the same length,":LOCATE 1,14:PRINT"even if they are."
3070 LOCATE 30,23:PRINT"PRESS ANY KEY TO CONTINUE"
3075 GOSUB 850
3080 GOSUB 845
3100 BORDER 0:CLS:MOVE 150,100:DRAW 490,100:MOVE 150,300:DRAW 490,300
3110 FOR DELAY=1 TO 3000:NEXT DELAY
3120 MOVE 150,100:DRAW 220,150:MOVE 150,100:DRAW 220,50:MOVE 490,100:DRAW 420,150:MOVE 490,100:DRAW 420,50
3130 MOVE 150,300:DRAW 80,350:MOVE 150,300:DRAW 80,250:MOVE 490,300:DRAW 560,350:MOVE 490,300:DRAW 560,250
3140 GOSUB 3800
3199 GOSUB 850:GOSUB 845
3200 CLS:MODE 2:PEN 1:INK 1,24
3210 LOCATE 1,1:PRINT"2: PONZO ILLUSION"
3220 LOCATE 1,4:PRINT"At first, you will see 2 lines that are of the same length."
3230 LOCATE 1,6:PRINT"But when we add background, these lines seem no more of the same length,":LOCATE 1,8:PRINT"even if they are."
3240 LOCATE 30,23:PRINT"PRESS ANY KEY TO CONTINUE"
3250 GOSUB 850:GOSUB 845
3300 DEX$=CHR$(214):ARI$=CHR$(215):FUL$=CHR$(143):MIK$=CHR$(240):FULK$=CHR$(143):GOTO 3301:DEX$=CHR$(222):ARI$=CHR$(223):FUL$=CHR$(127):GOTO 3301:FUL$=CHR$(207)
3301 SYMBOL AFTER 251: SYMBOL 254,0,0,0,0,24,60,126,255
3302 SYMBOL 255,60,60,60,60,60,60,60,60
3303 PSI$=CHR$(254):KOR$=CHR$(255)
3305 CLS:MODE 1:BORDER 0:PEN 1:INK 1,0:INK 0,26:INK 2,4:INK 3,9
3310 MOVE 300,300:DRAW 330,300:MOVE 300,30:DRAW 330,30
3312 FOR DELAY=1 TO 3000:NEXT DELAY:GOSUB 3800
3316 MOVE 190,1:DRAW 285,360:MOVE 440,1:DRAW 345,360
3318 PEN 3:LOCATE 8,19:PRINT DEX$+FUL$+FUL$+FUL$+ARI$:LOCATE 9,18:PRINT DEX$+FUL$+ARI$:LOCATE 10,17:PRINT PSI$ 
3320 PEN 2:LOCATE 10,20:PRINT FULK$:LOCATE 10,21:PRINT FULK$:LOCATE 10,22:PRINT FULK$
3350 PEN 2:LOCATE 13,12:PRINT KOR$:LOCATE 13,11:PRINT KOR$:PEN 3:LOCATE 12,10:PRINT DEX$+FUL$+ARI$:LOCATE 13,9:PRINT PSI$
3355 LOCATE 16,5:PRINT MIK$
3400 LOCATE 28,18:PRINT DEX$+FUL$+FUL$+FUL$+ARI$:LOCATE 29,17:PRINT DEX$+FUL$+ARI$:LOCATE 30,16:PRINT PSI$
3410 PEN 2:LOCATE 30,19:PRINT FULK$:LOCATE 30,20:PRINT FULK$:LOCATE 30,21:PRINT FULK$
3415 LOCATE 27,11:PRINT KOR$:LOCATE 27,10:PRINT KOR$:PEN 3:LOCATE 26,9:PRINT DEX$+FUL$+ARI$:LOCATE 27,8:PRINT PSI$
3420 PEN 3:LOCATE 24,4:PRINT MIK$
3450 FOR DIS=1 TO 5:MOVE 312+DIS,50:DRAW 312+DIS,120:NEXT DIS:FOR DIS=1 TO 3:MOVE 313+DIS,200:DRAW 313+DIS,240:NEXT DIS::MOVE 315,330:DRAW 315,345
3455 PEN 1:LOCATE 29,23:PRINT"50":MOVE 445,28:DRAW 445,52:DRAW 480,52:DRAW 480,28:DRAW 445,28:FOR PIN=1 TO 4:MOVE 461+PIN,28:DRAW 461+PIN,1:NEXT PIN
3459 GOSUB 850:GOSUB 845
3460 CLS:MODE 2:PEN 1:INK 1,24:BORDER 0:INK 0,0
3462 LOCATE 1,1:PRINT"3: COLOUR ILLUSION"
3464 LOCATE 1,4:PRINT"The squares in the centre have the same colour, but the green colour on the":LOCATE 1,6:PRINT"right appears to be darker, even if it is not.":LOCATE 30,23:PRINT"PRESS ANY KEY TO CONTINUE"
3466 GOSUB 850:GOSUB 845
3470 BORDER 1:MODE 1:INK 0,1:PEN 1:INK 1,24:PEN 2:INK 2,2:PEN 3:INK 3,21
3472 PEN 1:FUL$=CHR$(143):FULG$=FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$+FUL$:FULT$=FUL$+FUL$+FUL$+FUL$+FUL$
3474 FOR DIS=0 TO 14:LOCATE 6,5+DIS:PRINT FULG$:NEXT DIS
3476 PEN 2:FOR DIS=0 TO 14:LOCATE 21,5+DIS:PRINT FULG$:NEXT DIS
3478 PEN 3:FOR DIS=0 TO 4:LOCATE 11,10+DIS:PRINT FULT$:NEXT DIS:FOR DIS=0 TO 4:LOCATE 26,10+DIS:PRINT FULT$:NEXT DIS
3488 GOSUB 850:GOSUB 845
3490 RETURN
3500 REM SOUND DESIGN
3550 REM INTROS SOUNDS
3560 SOUND 1,119,8,14:SOUND 1,95,8,14:SOUND 1,60,8,14: REM CORR ANS CAPQ
3569 RETURN
3599 RETURN
3600 REM CORR ANS SOUND
3610 SOUND 1,119,10,10:SOUND 1,60,10,10
3649 RETURN
3650 REM WINNER SOUND
3670 SOUND 1,60,20,15:SOUND 1,80,5,15:SOUND 1,0,5:SOUND 1,80,10,15:SOUND 1,71,20,15:SOUND 1,80,10,15:SOUND 1,0,30:SOUND 1,63,20,15:SOUND 1,60,35,15
3699 RETURN
3700 REM WRONG ANS SOUND
3710 SOUND 1,300,35,15
3749 RETURN
3750 REM LOSE SOUND 
3760 SOUND 1,506,14,15:SOUND 1,568,14,15:SOUND 1,638,14,15:SOUND 1,716,14,15:SOUND 1,758,14,15:SOUND 1,851,14,15:SOUND 1,956,50,15
3799 RETURN
3800 REM INTRO S SOUND
3805 SOUND 1,119,10,15:SOUND 1,60,10,15
3810 RETURN
3820 REM MENU SOUND
3825 SOUND 1,119,20,15:SOUND 1,0,10,15:SOUND 1,119,10,15:SOUND 1,80,40,15
3829 RETURN
3830 REM CODE WRONG SOUND
3835 SOUND 1,300,35,15
3840 RETURN
3850 REM HIGHSCORE SOUND
3855 SOUND 1,119,10,14:SOUND 1,106,10,14:SOUND 1,95,10,14:SOUND 1,89,10,14:SOUND 1,80,10,14:SOUND 1,71,10,14:SOUND 1,67,10,14:SOUND 1,63,10,14:SOUND 1,60,20,14
3859 RETURN
3860 REM MIKRO SOUND 
3870 SOUND 1,119,8,14:SOUND 1,89,8,14:SOUND 1,60,8,14
3990 RETURN
4000 REM SECRET OPTION
4005 GOSUB 850
4010 MODE 2:PEN 1:INK 1,19:LOCATE 25,16:PRINT "ENTER SECRET CODE FOR 500 LIVES":LOCATE 40,18:INPUT"";COD$
4020 IF COD$="OFI" THEN LOCATE 38,22:PRINT"CORRECT!":CODE=1:GOSUB 3800:GOSUB 845:RETURN ELSE LOCATE 38,22:PRINT"WRONG!":CODE=0:GOSUB 3830:GOSUB 845:RETURN  
4100 REM SELECT DIFFICULTY
4105 GOSUB 850
4110 CLS:MODE 1:PEN 1:INK 1,15:LOCATE 13,7:PRINT"SELECT DIFFICULTY":LOCATE 13,11:PRINT "1. EASY":LOCATE 13,13:PRINT"2. NORMAL":LOCATE 13,15:PRINT"3. HARD":LOCATE 13,17:PRINT"4. YOU WILL LOSE"
4120 Q$=INKEY$
4122 IF Q$="1" THEN DIF=1:GOTO 4190 
4123 IF Q$="2" THEN DIF=2:GOTO 4190
4124 IF Q$="3" THEN DIF=3:GOTO 4190
4125 IF Q$="4" THEN DIF=4:GOTO 4190 
4130 GOTO 4120
4190 RETURN
4400 REM GAME END
4405 GOSUB 800:GOSUB 845
4407 GOSUB 850
4410 CLS:MODE 0:PEN 1:INK 1,6:LOCATE 6,10:GOSUB 3750:PRINT"GAME OVER":LOCATE 4,16:PRINT "SCORE:";SCORE:LOCATE 1,23:PRINT"PRESS SPACE TO RETRY"
4420 A$=INKEY$
4430 IF A$=" " THEN GOTO 140
4435 IF A$<>" " AND A$<>"" THEN GOTO 20
4440 GOTO 4420
4450 GOTO 20
4500 REM
4505 TIM=TIM-0.1:IF TIM<0 THEN RETURN 
4510 PEN 3:INK 3,26::LOCATE 18,23:PRINT USING"##.#";TIM
4520 RETURN
4700 REM AFTER
4710 PEN 1:LOCATE 8,21:PRINT"TIME IS OVER! LIFE LOST":ELIXE=1
4720 APA=0:AFT=1
4730 RETURN
5000 REM CAT1
5010 ON KEF GOSUB 5050,5100,5150,5200,5250,5300:RETURN
5050 PEN 1:INK 1,19:LOCATE 18,9:PRINT"XXXXX"
5060 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=2
5070 RETURN
5100 PEN 1:INK 1,19:LOCATE 18,9:PRINT YE$
5110 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=2
5140 RETURN
5150 PEN 1:INK 1,26:GOSUB 9800
5160 REM SVISTI PEN 1:INK 1,26::LOCATE 17,10:PRINT TR$
5170 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=2
5190 RETURN
5200 PEN 1:INK 1,26:GOSUB 9800:LOCATE 16,8:PRINT TE$
5220 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=2
5240 RETURN
5250 PEN 1:INK 1,19:GOSUB 9810
5260 PEN 3:INK 3,26:LOCATE 3,17:PRINT GR$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT GR$
5270 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT TE$:COR=3
5280 REM SVISTO META PEN 2:INK 2,26:LOCATE 17,8:PRINT TE$
5290 RETURN
5300 PEN 1:INK 1,19:GOSUB 9810
5305 PEN 1:LOCATE 16,7:PRINT GR$:LOCATE 16,8:PRINT TR$
5310 PEN 3:INK 3,26:LOCATE 3,17:PRINT GR$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT YE$
5320 LOCATE 3,18:PRINT TR$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT TE$:COR=2
5340 RETURN
5500 REM CAT2
5510 ON KEF GOSUB 5550,5600,5650,5700,5750,5800:RETURN
5550 PEN 1:INK 1,6::LOCATE 18,9:PRINT"XXXXX"
5560 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=3
5570 RETURN
5600 PEN 1:INK 1,19:LOCATE 18,9:PRINT RE$
5610 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=2
5640 RETURN
5650 PEN 1:INK 1,26:GOSUB 9800
5670 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=2
5690 RETURN
5700 PEN 1:INK 1,26:GOSUB 9800:LOCATE 16,8:PRINT TR$
5720 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=2
5740 RETURN
5750 PEN 1:INK 1,19:GOSUB 9840
5760 PEN 3:INK 3,26:LOCATE 3,17:PRINT GR$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT YE$
5770 LOCATE 3,18:PRINT TR$:LOCATE 18,18:PRINT PE$:LOCATE 31,18:PRINT TR$:COR=1
5790 RETURN
5800 PEN 1:INK 1,19:GOSUB 9840
5805 PEN 1:LOCATE 16,9:PRINT RE$:LOCATE 16,10:PRINT TR$
5810 PEN 3:INK 3,26:LOCATE 3,17:PRINT GR$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT GR$
5820 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TR$:LOCATE 31,18:PRINT TR$:COR=3
5840 RETURN
5990 RETURN
6000 REM CAT3
6010 ON KEF GOSUB 6050,6100,6150,6200,6250,6300:RETURN
6050 PEN 1:INK 1,24::LOCATE 18,9:PRINT"XXXXX"
6060 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=1
6070 RETURN
6100 PEN 1:INK 1,19:LOCATE 18,9:PRINT GR$ 
6110 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=2
6140 RETURN
6150 PEN 1:INK 1,26:GOSUB 9800
6170 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=2
6190 RETURN
6200 PEN 1:INK 1,26:GOSUB 9800:LOCATE 16,8:PRINT PE$
6220 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=2
6240 RETURN
6250 PEN 1:INK 1,19:GOSUB 9850
6260 PEN 3:INK 3,26:LOCATE 3,17:PRINT RE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT GR$
6270 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT PE$:LOCATE 31,18:PRINT TE$:COR=2
6290 RETURN
6300 PEN 1:INK 1,19:GOSUB 9850
6305 PEN 1:LOCATE 17,8:PRINT GR$:LOCATE 17,9:PRINT TE$
6310 PEN 3:INK 3,26:LOCATE 3,17:PRINT GR$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT GR$
6320 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TR$:LOCATE 31,18:PRINT TE$:COR=1
6340 RETURN
6490 RETURN
6500 REM CAT4
6510 ON KEF GOSUB 6550,6600,6650,6700,6750,6800:RETURN
6550 PEN 1:INK 1,19:LOCATE 18,9:PRINT"XXXXX"
6560 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=2
6570 RETURN
6600 PEN 1:INK 1,24:LOCATE 18,9:PRINT YE$
6610 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=1
6640 RETURN
6650 PEN 1:INK 1,26:GOSUB 9830
6670 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=3
6690 RETURN
6700 PEN 1:INK 1,26:GOSUB 9830:LOCATE 16,10:PRINT PE$
6720 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=3
6740 RETURN
6750 PEN 1:INK 1,24:GOSUB 9810
6760 PEN 3:INK 3,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT YE$
6770 LOCATE 3,18:PRINT TE$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT PE$:COR=1
6790 RETURN
6800 PEN 1:INK 1,24:GOSUB 9810
6805 PEN 1:LOCATE 16,7:PRINT RE$:LOCATE 16,8:PRINT TE$
6810 PEN 3:INK 3,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT YE$:LOCATE 31,17:PRINT RE$
6820 LOCATE 3,18:PRINT TR$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT TE$:COR=2
6840 RETURN
6990 RETURN
7000 REM CAT5
7010 ON KEF GOSUB 7050,7100,7150,7200,7250,7300:RETURN
7050 PEN 1:INK 1,6:LOCATE 18,9:PRINT"XXXXX"
7060 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=3
7070 RETURN
7100 PEN 1:INK 1,24:LOCATE 18,9:PRINT GR$
7110 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=1
7140 RETURN
7150 PEN 1:INK 1,26:GOSUB 9830
7170 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=3
7190 RETURN
7200 PEN 1:INK 1,26:GOSUB 9830:LOCATE 16,10:PRINT TR$
7220 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=3
7240 RETURN
7250 PEN 1:INK 1,24:GOSUB 9840
7260 PEN 3:INK 3,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT YE$:LOCATE 31,17:PRINT RE$
7270 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TR$:LOCATE 31,18:PRINT TR$:COR=2
7290 RETURN
7300 PEN 1:INK 1,24:GOSUB 9840
7305 PEN 1:LOCATE 16,9:PRINT YE$:LOCATE 16,10:PRINT TR$
7310 PEN 3:INK 3,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT YE$
7320 LOCATE 3,18:PRINT TE$:LOCATE 18,18:PRINT TR$:LOCATE 31,18:PRINT TR$:COR=3
7340 RETURN
7490 RETURN
7500 REM CAT6
7510 ON KEF GOSUB 7550,7600,7650,7700,7750,7800:RETURN
7550 PEN 1:INK 1,24:LOCATE 18,9:PRINT"XXXXX"
7560 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=1
7570 RETURN
7600 PEN 1:INK 1,24:LOCATE 18,9:PRINT RE$ 
7610 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=1
7640 RETURN
7650 PEN 1:INK 1,26:GOSUB 9830
7670 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=3
7690 RETURN
7700 PEN 1:INK 1,26:GOSUB 9830:LOCATE 16,10:PRINT TE$
7720 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=3
7740 RETURN
7750 PEN 1:INK 1,24:GOSUB 9850
7760 PEN 3:INK 3,26:LOCATE 3,17:PRINT RE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT YE$
7770 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT PE$:LOCATE 31,18:PRINT PE$:COR=3
7790 RETURN
7800 PEN 1:INK 1,24:GOSUB 9850
7805 PEN 1:LOCATE 17,8:PRINT RE$:LOCATE 17,9:PRINT PE$
7810 PEN 3:INK 3,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT YE$:LOCATE 31,17:PRINT RE$
7820 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TR$:LOCATE 31,18:PRINT PE$:COR=1
7840 RETURN
7990 RETURN
8000 REM CAT7
8010 ON KEF GOSUB 8050,8100,8150,8200,8250,8300:RETURN
8050 PEN 1:INK 1,19:LOCATE 18,9:PRINT"XXXXX"
8060 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=2
8070 RETURN
8100 PEN 1:INK 1,6:LOCATE 18,9:PRINT RE$
8110 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=3
8140 RETURN
8150 PEN 1:INK 1,26:GOSUB 9860
8170 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=1
8190 RETURN
8200 PEN 1:INK 1,26:GOSUB 9860:LOCATE 16,10:PRINT PE$
8220 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=1
8240 RETURN
8250 PEN 1:INK 1,6:GOSUB 9810
8260 PEN 3:INK 3,26:LOCATE 3,17:PRINT RE$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT YE$ 
8270 LOCATE 3,18:PRINT TR$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT TE$:COR=2
8290 RETURN
8300 PEN 1:INK 1,6:GOSUB 9810
8305 PEN 1:LOCATE 16,7:PRINT RE$:LOCATE 16,8:PRINT PE$
8310 PEN 3:INK 3,26:LOCATE 3,17:PRINT RE$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT RE$ 
8320 LOCATE 3,18:PRINT TE$:LOCATE 18,18:PRINT TR$:LOCATE 31,18:PRINT PE$:COR=1
8340 RETURN
8490 RETURN
8500 REM CAT8
8510 ON KEF GOSUB 8550,8600,8650,8700,8750,8800:RETURN
8550 PEN 1:INK 1,6:LOCATE 18,9:PRINT"XXXXX"
8560 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=3
8570 RETURN
8600 PEN 1:INK 1,6:LOCATE 18,9:PRINT YE$
8610 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=3
8640 RETURN
8650 PEN 1:INK 1,26:GOSUB 9860
8670 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=1
8690 RETURN
8700 PEN 1:INK 1,26:GOSUB 9860:LOCATE 17,10:PRINT TE$
8720 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=1
8740 RETURN
8750 PEN 1:INK 1,6:GOSUB 9840
8760 PEN 3:INK 3,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT RE$
8770 LOCATE 3,18:PRINT TR$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT TR$:COR=3 
8790 RETURN
8800 PEN 1:INK 1,6:GOSUB 9840
8805 PEN 1:LOCATE 16,9:PRINT RE$:LOCATE 16,10:PRINT TE$
8810 PEN 3:INK 3,26:LOCATE 3,17:PRINT RE$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT GR$
8820 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TR$:LOCATE 31,18:PRINT TR$:COR=2
8840 RETURN
8990 RETURN
9000 REM CAT9
9010 ON KEF GOSUB 9050,9100,9150,9200,9250,9300:RETURN
9050 PEN 1:INK 1,24:LOCATE 18,9:PRINT"XXXXX"
9060 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=1
9070 RETURN
9100 PEN 1:INK 1,6:LOCATE 18,9:PRINT GR$
9110 PEN 2:INK 2,26:LOCATE 3,17:PRINT YE$:LOCATE 18,17:PRINT GR$:LOCATE 31,17:PRINT RE$:COR=3
9140 RETURN
9150 PEN 1:INK 1,26:GOSUB 9860
9170 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=1
9190 RETURN
9200 PEN 1:INK 1,26:GOSUB 9860:LOCATE 17,10:PRINT TR$
9220 PEN 1:INK 1,26:LOCATE 3,17:PRINT PE$:LOCATE 18,17:PRINT TE$:LOCATE 31,17:PRINT TR$:COR=1
9240 RETURN
9250 PEN 1:INK 1,6:GOSUB 9850
9260 PEN 3:INK 3,26:LOCATE 3,17:PRINT RE$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT RE$
9270 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT TR$:COR=1
9290 RETURN
9300 PEN 1:INK 1,6:GOSUB 9850
9305 PEN 1:LOCATE 17,8:PRINT GR$:LOCATE 17,9:PRINT PE$
9310 PEN 3:INK 3,26:LOCATE 3,17:PRINT GR$:LOCATE 18,17:PRINT RE$:LOCATE 31,17:PRINT RE$ 
9320 LOCATE 3,18:PRINT PE$:LOCATE 18,18:PRINT TE$:LOCATE 31,18:PRINT PE$:COR=3
9340 RETURN
9450 RETURN
9800 MOVE 238,216:DRAW 384,216:DRAW 384,360:DRAW 238,360:DRAW 238,216:RETURN:REM TETRAGONO 
9810 REM TETRAGONO XROMATISTO
9815 FOR D=0 TO 146:MOVE 238,216+D:DRAW 384,216+D:NEXT D
9820 RETURN
9830 REM APLO TRIGONO
9835 MOVE 197,226:DRAW 417,226:DRAW 307,340:DRAW 197,226
9839 RETURN
9840 REM TRIGONO XROMATISTO
9841 FOR D=0 TO 110:MOVE 197+D,226+D:DRAW 417-D,226+D:NEXT D
9849 RETURN
9850 REM TRAPEZIUM XROMATISMENO
9851 FOR D=0 TO 60:MOVE 203+D,226+D*1.5:DRAW 439-D,226+D*1.5:NEXT D
9860 REM TRAPEZIO APLO
9861 MOVE 203,226:DRAW 439,226:DRAW 380,316:DRAW 262,316:DRAW 203,226
9870 RETURN
9890 RETURN
10000 REM GREEK GLOSSA
10010 SYMBOL AFTER 250
10015 SYMBOL 250,24,24,60,60,60,189,126,60
10020 SYMBOL 251,126,102,102,102,102,102,102
10030 SYMBOL 252,124,96,96,96,96,96,96 
10035 SYMBOL 253,124,198,198,198,198,108,238
10040 KO$="KOKKINO":PR$=CHR$(251)+"PA"+CHR$(190)+"INO":KI$="KITPINO"
10050 GO$="TETPA"+CHR$(252)+CHR$(253)+"NO":NO$="TPI"+CHR$(252)+CHR$(253)+"NO":ZI$="TPA"+CHR$(251)+"EZIO"
10060 RETURN
10100 REM DEV EXTRA
10110 LOCATE 2,25:PRINT"EXTRA LIFE!"
10115 PEN 2:INK 2,24
10120 LOCATE 5,24:PRINT CHR$(145):LOCATE 5,23:PRINT CHR$(149):
10140 PEN 2:INK 2,24:LOCATE 5,22:PRINT CHR$(250):PEN 3
10500 RETURN