5 REM COPYRIGHT BY SAKIS KAFFESAKIS 2020.
6 GOSUB 5000  
7 CLS:MODE 1:PEN 1:INK 1,26:BORDER 0:INK 0,0:GOSUB 2500
10 REM
15 SOUND 1,119,15,15:SOUND 1,106,15,15:SOUND 1,95,15,15:SOUND 1,80,30,15:SOUND 1,95,15,15:SOUND 1,80,30,15 
20 CLS:MODE 1:BORDER 11:PEN 3:INK 3,20:INK 0,0:RANDOMIZE TIME   
30 LOCATE 7,5:PRINT "Welcome to..." 
50 FOR delay=1 TO 200:NEXT delay:LOCATE 15,9:PEN 2:INK 2,18:PRINT "BARBOUTI!!!" 
60 PEN 2:LOCATE 15,12:PRINT"(DICE GAME)":PEN 1:INK 1,15:LOCATE 13,15:PRINT"1. START GAME":LOCATE 13,17:PRINT"2. INSTRUCTIONS":LOCATE 13,19:PRINT"3. HISTORY"
90 LOCATE 8,22:PEN 3:PRINT"by SAKIS KAFFESAKIS":LOCATE 28,22:PRINT CHR$(164):LOCATE 30,22:PRINT"2020":LOCATE 7,24:PRINT"www.amstradsakis.blogspot.com":MOVE 90,15:DRAW 565,15 
100 A$=INKEY$
110 IF A$="2" THEN GOSUB 2000:GOTO 20 
112 IF A$="3" THEN GOSUB 2200:GOTO 20
114 IF A$="1" THEN GOTO 120
116 GOTO 100
120 CLS:PEN 1:INK 1,18
130 LOCATE 5,18:PRINT"FOR ONE PLAYER GAME PRESS 1"
140 LOCATE 5,20:PRINT"FOR TWO PLAYER GAME PRESS 2"
150 A$=INKEY$
160 IF A$="1" THEN G=1:GOTO 200
170 IF A$="2" THEN G=2:GOTO 200
180 IF A$="" THEN GOTO 150
190 IF a$<>"1" AND  a$<>"2" THEN GOTO 150 
200 CLS:LOCATE 10,10:INPUT"NAME OF PLAYER 1? ",OFI$
210 IF G=1 THEN OLY$="CPC GAMBLER":GOTO 230
220 LOCATE 10,12:INPUT "NAME OF PLAYER 2? ", OLY$ 
230 Y=20000:X=20000
235 P1$=LEFT$(OFI$,11):P2$=LEFT$(OLY$,11)
240 GOTO 251
250 END
251 PLIK=1::Y=20000:X=20000:KAKIA=0:NNB=2:BANK1=0:BANK2=0:WATCH1=0:WATCH2=0:AKOL=0:WINNER$=""
255 REM START GAME
256 KAKIA=0:WIN=0:BCHANGE=0:WCHANGE=0:EXT=0
260 MODE 1
270 PEN 1:INK 1,26:MOVE 20,175:DRAW 20,20:DRAW 225,20:DRAW 225,175:DRAW 20,175
280 MOVE 620,175:DRAW 620,20:DRAW 415,20:DRAW 415,175:DRAW 620,175
290 PEN 2: INK 2,19:LOCATE 3,16:PRINT "PLAYER 1":LOCATE 3,18: PRINT LEFT$(OFI$,11):LOCATE 6,21:PRINT "TOTAL":LOCATE 5,23:PRINT X
300 LOCATE 28,16:PRINT"PLAYER 2":LOCATE 28,18:PRINT LEFT$(OLY$,11):LOCATE 31,21:PRINT"TOTAL":LOCATE 30,23:PRINT Y:LOCATE 1,1:PEN 1
410 PEN 1:IF PLIK=1 THEN LOCATE 3,14:PRINT"HOLDS DICE":IF NNB=2 THEN LOCATE 28,14:PRINT"DECIDES BET"
420 PEN 1:IF PLIK=2 THEN LOCATE 28,14:PRINT"HOLDS DICE":IF NNB=2 THEN LOCATE 3,14:PRINT"DECIDES BET"
423 PEN 3:INK 3,15:GOSUB 4500:IF NNB=1 OR BCHANGE=1 OR WCHANGE=1 THEN GOTO 433
425 GOSUB 4500:IF BCHANGE=1 THEN GOTO 433
426 IF PLIK=1 AND G=1 THEN GOSUB 6000:GOTO 433
430 LOCATE 16,19:INPUT"BET";BET:IF BET>X OR BET>Y THEN LOCATE 16,19:PRINT SPC(20):MOVE 415,20:DRAW 415,175:GOTO 430
433 IF G=1 AND PLIK=2 THEN LOCATE 16,19:PRINT"BET=":LOCATE 20,19:PRINT bet;SPC(12):LOCATE 5,2:PRINT P2$;" IS THROWING DICE...":GOTO 442
435 LOCATE 16,19:PRINT"BET=":LOCATE 20,19:PRINT bet;SPC(12):LOCATE 5,2:PRINT"PRESS SPACE TO THROW DICE":MOVE 415,20:DRAW 415,175:GOTO 450
442 MOVE 415,20:DRAW 415,175:REM EMPTY
450 W$=INKEY$
455 IF G=1 AND PLIK=2 THEN GOSUB 7550:GOTO 470
460 IF W$="B" OR W$="b" THEN GOSUB 8400 
462 IF W$="S" OR W$="s" THEN GOSUB 8700
468 IF W$<>" " THEN GOTO 450
470 RANDOMIZE TIME:DZ1=RND:Z1=INT(DZ1*6)+1 
475 GOSUB 5100
480 PEN 1:ON Z1 GOSUB 3000,3020,3040,3060,3080,3100
490 PEN 3:RANDOMIZE TIME:ZEXO=RND:IF ZEXO<0.1 THEN GOSUB 7000
495  REM GOSUB 7000 REM FIXED ZEXO
500 IF KAKIA=1 THEN LOCATE 15,4:PRINT"LOST TURN":DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:DD$=INKEY$:GOSUB 7100:NNB=1:WIN=2:GOTO 700
505 IF KAKIA=2 AND G=1 AND PLIK=2 THEN GOSUB 7550:LOCATE 15,4:PRINT P2$;" PLAYS THE BAD":GOSUB 9500:GOSUB 7550:GOTO 520
510 IF KAKIA=2 THEN LOCATE 15,4:PRINT"PLAY THE BAD":GOSUB 9500:GOSUB 7100
520 RANDOMIZE TIME:DZ2=RND:Z2=INT(DZ2*6)+1
525 IF KAKIA=2 THEN GOSUB 5200
527 EXT=INT(RND*10):IF KAKIA=0 THEN FOR DELAY=1 TO 50+25*EXT:NEXT DELAY:IF EXT>4 THEN SOUND 1,2200,10,8,0,0,5
530 PEN 1:ON Z2 GOSUB 4000,4020,4040,4060,4080,4100
540 IF PLIK=1 THEN GOSUB 8000
550 IF PLIK=2 THEN GOSUB 8100
592 IF NNB=2 THEN GOSUB 7500:GOSUB 5500:PEN 3:LOCATE 17,11:PRINT WIN$:LOCATE 17,13:PRINT "WINS!":GOSUB 7100:LOCATE 5,23:PRINT "      ":LOCATE 5,23:PRINT X:LOCATE 30,23:PRINT"      ":LOCATE 30,23:PRINT Y:DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:GOSUB 7100:GOTO 700
600 DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:DD$=INKEY$:GOSUB 7100
700 IF WIN=1 THEN PLIK=PLIK:GOTO 998
710 IF WIN=2 OR WIN=0 THEN GOTO 720
720 IF PLIK=1 THEN PLIK=2:GOTO 740
730 IF PLIK=2 THEN PLIK=1
740 GOTO 998
998 IF X=0 OR Y=0 THEN GOTO 1000
999 DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:DD$=INKEY$:DE$=INKEY$:GOTO 255
1000 IF X=0 THEN WINNER$=P2$
1010 IF Y=0 THEN WINNER$=P1$ 
1020 PEN 3:CLS:LOCATE 16,10:PRINT WINNER$:LOCATE 16,13:PRINT"WINS!!!"
1030 LOCATE 4,23:PRINT "PRESS SPACE TO SEE HOW STORY ENDS"
1035 GOSUB 3200
1037 DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:DD$=INKEY$
1050 T$=INKEY$
1060 REM EDO TO STELNEI GIA RESTART IF T$="1" THEN GOTO 251
1070 IF T$=" " THEN GOTO 1400
1080 GOTO 1050
1400 REM SCENARIOS TEST
1401 GOSUB 5400:MODE 2:PEN 1:INK 1,26
1402 GOSUB 1600
1410 LOCATE 2,2:PRINT P1$
1420 LOCATE 1,4:PRINT SFA1$:LOCATE 1,6:PRINT SFA2$:LOCATE 1,8:PRINT SFA3$:LOCATE 1,10:PRINT SFA4$
1422 PLOT 1,217:DRAW 640,217:PLOT 1,40:DRAW 640,40
1425 IF G=1 THEN GOTO 1450
1430 LOCATE 2,13:PRINT P2$
1440 LOCATE 1,15:PRINT SFB1$:LOCATE 1,17:PRINT SFB2$:LOCATE 1,19:PRINT SFB3$:LOCATE 1,21:PRINT SFB4$ 
1450 LOCATE 22,24:PRINT"PRESS 1 TO PLAY AGAIN OR 2 TO RESTART"
1455 DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:DD$=INKEY$
1460 Q$=INKEY$
1470 IF Q$="1" THEN GOTO 251
1480 IF Q$="2" THEN GOTO 10
1490 GOTO 1460
1600 REM SCENARIOS!
1605 IF P1$=WINNER$ THEN SFA1$="You spent most of the money you won in drinking at bars.":SFB1$="You spent all the money that you were trying to keep for 2 years."
1610 IF P2$=WINNER$ THEN SFB1$="You spent almost most of the money you won in drinking at bars.":SFA1$="You spent all the money that you were trying to keep for 2 years." 
1620 IF BANK1=1 THEN SFA2$="The capitalist bank will sell your house if you don't pay your debts." ELSE SFA2$="At least, you didn't get a loan, so your house is safe."
1630 IF BANK2=1 THEN SFB2$="The capitalist bank will sell your house if you don't pay your debts." ELSE SFB2$="At least, you didn't get a loan, so your house is safe."
1640 IF WATCH1=1 THEN SFA3$="Your wife is very angry for selling her present and is thinking the divorce." ELSE SFA3$="Your wife is disappointed from you gambling all saved money for 2 years."
1650 IF WATCH2=1 THEN SFB3$="Your wife is very angry for selling her present and is thinking the divorce." ELSE SFB3$="Your wife is disappointed from you gambling all saved money for 2 years."
1700 REM SF4!!!! COMPLICATED
1710 IF P1$=WINNER$ AND BANK1=1 AND WATCH1=1 THEN SFA4$="Finally, your wife leaves and you have to work 12 hours a day so that you pay your dept and keep your (empty) house."
1720 IF P1$<>WINNER$ AND BANK1=1 AND WATCH1=1 THEN SFA4$="Finally, you lost everything. Your wife left, your house was sold by the capitalist bank, and you have no money."
1730 IF P2$=WINNER$ AND BANK2=1 AND WATCH2=1 THEN SFB4$="Finally, your wife leaves and you have to work 12 hours a day so that you pay your dept and keep your (empty) house."
1740 IF P2$<>WINNER$ AND BANK2=1 AND WATCH2=1 THEN SFB4$="Finally, you lost everything. Your wife left, your house was sold by the capitalist bank, and you have no money."
1750 IF P1$=WINNER$ AND BANK1=0 AND WATCH1=1 THEN SFA4$="Finally, your wife leaves you. You have your house, but it is full of memories, so it is a sad place now.You spent all rest gained money in drinking about her."
1760 IF P1$<>WINNER$ AND BANK1=0 AND WATCH1=1 THEN SFA4$="Finally, your wife leaves you. You have your house, but no money and an empty refrigerator."
1770 IF P2$=WINNER$ AND BANK2=0 AND WATCH2=1 THEN SFB4$="Finally, your wife leaves you. You have your house, but it is full of memories, so it is a sad place now.You spent all rest gained money in drinking about her."
1780 IF P2$<>WINNER$ AND BANK2=0 AND WATCH2=1 THEN SFB4$="Finally, your wife leaves you. You have your house, but no money and an empty refrigerator."
1790 IF P1$=WINNER$ AND BANK1=1 AND WATCH1=0 THEN SFA4$="Finally, your wife forgives you. But the capitalist bank sold your house.You spent all money left in buying a very old and small house and will try a new start."
1800 IF P1$<>WINNER$ AND BANK1=1 AND WATCH1=0 THEN SFA4$="Finally, your wife forgives you. But the capitalist bank sold your house. You are living now with your wife temporarily in your car."
1810 IF P2$=WINNER$ AND BANK2=1 AND WATCH2=0 THEN SFB4$="Finally, your wife forgives you. But the capitalist bank sold your house.You spent all money left in buying a very old and small house and will try a new start."
1820 IF P2$<>WINNER$ AND BANK2=1 AND WATCH2=0 THEN SFB4$="Finally, your wife forgives you. But the capitalist bank sold your house. You are living now with your wife temporarily in your car."
1830 IF P1$=WINNER$ AND BANK1=0 AND WATCH1=0 THEN SFA4$="Finally, your wife forgives you. All rest gained money were spent in addiction therapy. You have a second chance now. Don't waste it."
1840 IF P1$<>WINNER$ AND BANK1=0 AND WATCH1=0 THEN SFA4$="Finally, your wife forgives you. You have to work 12 hours daily to earn again the money you lost. But, at least, you have a second chance now, don't waste it."
1850 IF P2$=WINNER$ AND BANK2=0 AND WATCH2=0 THEN SFB4$="Finally, your wife forgives you. All rest gained money were spent in addiction therapy. You have a second chance now. Don't waste it."
1860 IF P2$<>WINNER$ AND BANK2=0 AND WATCH2=0 THEN SFB4$="Finally, your wife forgives you. You have to work 12 hours daily to earn again the money you lost. But, at least, you have a second chance now, don't waste it."
1999 RETURN
2000 REM INSTRUCTIONS
2010 MODE 2:PEN 1:INK 1,26:LOCATE 32,2:PRINT"INSTRUCTIONS (1)"
2020 LOCATE 1,4:PRINT"BARBOUTI is a dice game based completely in luck."
2030 LOCATE 1,6:PRINT"At first, the one player holds the dice (and throws them), while the other player decides the bet."
2040 LOCATE 1,8:PRINT"There are 3 possibilities depending on what are the numbers on the dice. The player who throws the dice can win,lose, or remain undecided (in this case he gives the dice to the next player, etc)."
2050 LOCATE 1,11: PRINT"There is no difference if you throw the dice and win, or if the opponent throws the dice and loses."
2060 LOCATE 5,14:PRINT"WINNING COMBINATIONS":LOCATE 50,14:PRINT"LOSE COMBINATIONS"
2070 LOCATE 5,16:PRINT"6   6":LOCATE 5,18:PRINT "6   5 (or 5   6)"::LOCATE 5,20:PRINT"5   5":LOCATE 5,22:PRINT"3   3"
2080 LOCATE 50,16:PRINT"1   1":LOCATE 50,18:PRINT "1   2 (or 2   1)":LOCATE 50,20:PRINT"2   2":LOCATE 50,22:PRINT"4   4"
2085 LOCATE 1,24:PRINT"Sequence of the numbers (eg. if it is 5 and 6, or 6 and 5) plays no role."
2086 VA$=INKEY$:VB$=INKEY$:VC$=INKEY$
2090 GOSUB 7100
2100 CLS:LOCATE 32,2:PRINT"INSTRUCTIONS (2)"
2110 LOCATE 1,4:PRINT"Sometimes, one dice (by mistake) is thrown out of the table. In the game, there is a 10% of this to happen in each turn."
2120 LOCATE 1,6:PRINT"If this happens, following rules apply:If the one dice thrown in the table is a <good> one (3,5 or 6), then you lose uour turn. If it is a <bad> one (1,2 or 4), then you throw only the second dice." 
2125 LOCATE 1,9:PRINT"This means that best result is not to lose, as there are no winning combinations with 1,2 or 4."
2130 LOCATE 1,11:PRINT"If a player wins, he keeps the dice and the other player decides the bet. If a player loses, he gives the dice and he decides the bet."
2140 LOCATE 1,14:PRINT"In this game, we added 2 extras: When you have the dice, and after other player deciding the bet, you have the options <Bank> AND <Watch>."
2150 LOCATE 1,16:PRINT"If you choose <Bank> option, you can take a loan from the capitalist bank. This can be 2500-5000, depending on luck."
2160 LOCATE 1,18:PRINT"If you choose <Watch> option, you can sell your watch.This can give you 1500-3000, depending on luck." 
2173 LOCATE 1,20:PRINT"These extras can give you an advantage, but they affect the <end of the story>."
2175 LOCATE 35,22:PRINT"HAVE FUN!!!"
2180 LOCATE 23,24:PRINT"PRESS SPACE FOR MENU OR B TO GO BACK":DA$=INKEY$:DB$=INKEY$:DC$=INKEY$
2181 U$=INKEY$ 
2182 IF U$=" " THEN GOTO 2190
2183 IF U$="B" OR U$="b" THEN GOTO 2000
2185 GOTO 2181
2190 RETURN 
2200 REM HISTORY
2205 MODE 2:PEN 1:INK 1,26:LOCATE 36,2:PRINT"HISTORY"
2210 LOCATE 1,4:PRINT "BARBOUTI is a traditional and very polular dice game in Greece."
2220 LOCATE 1,6:PRINT "The word probably comes from the turkish word <Barbut>."
2230 LOCATE 1,8:PRINT "Its popularity is based on its simplicity and also on the fact that it is a perfectly fair game (each player has exactly 50% to win)."
2240 LOCATE 1,11:PRINT"Unfortunately, BARBOUTI is much associated with gambling. It is mostly played on christmas period, in houses and coffee shops, usually in a large table, and by many players (not only 2-player game)."
2250 LOCATE 1,15:PRINT"During playing BARBOUTI, many people have lost gigantic amounts of money, watches, or even houses."  
2260 LOCATE 1,18:PRINT"This game wants to show that gambling can have 2 types of consequences:very bad, and even worse. Never good."
2270 LOCATE 1,21:PRINT"Credit must go to my friend Michalis (Kouros) for giving me the idea of making a game based on BARBOUTI."
2275 LOCATE 29,24:PRINT"PRESS ANY KEY FOR MENU"
2380 DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:GOSUB 7100 
2390 RETURN
2500 REM INTRO LOADING SCREEN
2506 INK 1,19
2513 PLOT 300,58:DRAW 300,1:PLOT 340,53:DRAW 340,1
2514 PLOT 188,190:DRAW 188,30:PLOT 218,170:DRAW 218,30:DRAW 188,30
2515 PLOT 584,210:DRAW 584,90:PLOT 559,200:DRAW 559,90:DRAW 584,90
2516 PEN 2:INK 2,26
2521 FOR GR=1 TO 39:PLOT 300+GR,1:DRAW 300+GR,48:NEXT GR
2522 FOR GR=1 TO 29:PLOT 188+GR,30:DRAW 188+GR,166:NEXT GR
2523 FOR GR=1 TO 24:PLOT 559+GR,90:DRAW 559+GR,197:NEXT GR 
2524 PLOT 192,177:DRAW 192,166:PLOT 192,177:DRAW 200,166:DRAW 188,180:PLOT 192,175:DRAW 195,166
2525 PLOT 302,55:DRAW 302,48:PLOT 302,55:DRAW 306,48:PLOT 308,51
2526 PLOT 582,200:DRAW 574,199:PLOT 582,208:DRAW 582,197:PLOT 580,201:PLOT 578,200:PLOT 579,201:PLOT 579,202:PLOT 578,202
2530 FOR GR=1 TO 157:MOVE 320-0.9*GR,40+GR:DRAW 592-0.9*GR,212+GR:NEXT GR 
2532 PLOT 14,145:DRAW 14,95:DRAW 64,95:DRAW 64,145:DRAW 14,145 
2534 PLOT 110,145:DRAW 110,95:DRAW 161,95:DRAW 161,145:DRAW 110,145
2535 LOCATE 2,17:PRINT K$:LOCATE 4,17:PRINT K$:LOCATE 2,18:PRINT K$:LOCATE 4,18:PRINT K$:LOCATE 2,19:PRINT K$:LOCATE 4,19:PRINT K$
2536 LOCATE 8,17:PRINT K$:LOCATE 10,17:PRINT K$:LOCATE 9,18:PRINT K$:LOCATE 8,19:PRINT K$:LOCATE 10,19:PRINT K$
2537 F$=CHR$(224):S$=CHR$(143):FT$=CHR$(225):XED$=CHR$(205):XEA$=CHR$(204)
2538 LOCATE 18,6:PRINT F$:LOCATE 14,9:PRINT F$:LOCATE 23,3:PRINT F$:LOCATE 33,4:PRINT F$:LOCATE 36,7:PRINT F$
2539 PEN 3:INK 3,15:LOCATE 18,7:PRINT S$:LOCATE 18,8:PRINT S$:LOCATE 17,7:PRINT XEA$:LOCATE 19,7:PRINT XED$
2540 LOCATE 14,10:PRINT S$:LOCATE 14,11:PRINT S$:LOCATE 13,10:PRINT XEA$:LOCATE 15,10:PRINT XED$
2550 LOCATE 23,4:PRINT S$:LOCATE 23,5:PRINT S$:LOCATE 22,4:PRINT XEA$:LOCATE 24,4:PRINT XED$
2560 LOCATE 33,5:PRINT S$:LOCATE 33,6:PRINT S$:LOCATE 32,5:PRINT XEA$:LOCATE 34,5:PRINT XED$
2570 LOCATE 36,8:PRINT S$:LOCATE 36,9:PRINT S$:LOCATE 35,8:PRINT XEA$:LOCATE 37,8:PRINT XED$
2590 PEN 1:LOCATE 10,1:PRINT"B A R B O U T I ! ! !":GOSUB 5300:FOR DELAY=1 TO 600:NEXT DELAY:LOCATE 1,6:PRINT"PRESS ANY KEY!"
2595 DA$=INKEY$:DB$=INKEY$:DC$=INKEY$:DD$=INKEY$:GOSUB 7100
2980 LOCATE 1,1:PEN 1
2999 RETURN
3000 REM ZARI A1
3010 LOCATE 17,7:PRINT K$:GOSUB 5040:RETURN 
3020 REM ZARI A2
3030 LOCATE 18,6:PRINT K$:LOCATE 16,8:PRINT K$:GOSUB 5040:RETURN
3040 REM ZARI A3
3050 LOCATE 16,6:PRINT K$:LOCATE 17,7:PRINT K$:LOCATE 18,8:PRINT K$:GOSUB 5040:RETURN
3060 REM ZARI A4
3070 LOCATE 16,6:PRINT K$:LOCATE 18,6:PRINT K$:LOCATE 16,8:PRINT K$:LOCATE 18,8:PRINT K$:GOSUB 5040:RETURN
3080 REM ZARI A5
3090 LOCATE 16,6:PRINT K$:LOCATE 18,6:PRINT K$:LOCATE 17,7:PRINT K$:LOCATE 16,8:PRINT K$:LOCATE 18,8:PRINT K$:GOSUB 5040:RETURN
3100 REM ZARI A6
3110 LOCATE 16,6:PRINT K$:LOCATE 18,6:PRINT K$:LOCATE 16,7:PRINT K$:LOCATE 18,7:PRINT K$:LOCATE 16,8:PRINT K$:LOCATE 18,8:PRINT K$:GOSUB 5040:RETURN
3200 REM SOUND OF WINNING
3210 SOUND 1,60,20,5:SOUND 1,80,5,5:SOUND 1,0,5:SOUND 1,80,10,5:SOUND 1,71,20,5:SOUND 1,80,15,5:SOUND 1,0,30:SOUND 1,63,20,5:SOUND 1,60,30,5
3220 FOR DELAY=1 TO 800:NEXT DELAY
3290 RETURN
4000 REM ZARI B1
4010 LOCATE 23,7:PRINT K$:GOSUB 5070:RETURN 
4020 REM ZARI B2
4030 LOCATE 24,6:PRINT K$:LOCATE 22,8:PRINT K$:GOSUB 5070:RETURN 
4040 REM ZARI B3
4050 LOCATE 22,6:PRINT K$:LOCATE 23,7:PRINT K$:LOCATE 24,8:PRINT K$:GOSUB 5070:RETURN
4060 REM ZARI B4
4070 LOCATE 22,6:PRINT K$:LOCATE 24,6:PRINT K$:LOCATE 22,8:PRINT K$:LOCATE 24,8:PRINT K$:GOSUB 5070:RETURN 
4080 REM ZARI B5
4090 LOCATE 22,6:PRINT K$:LOCATE 24,6:PRINT K$:LOCATE 23,7:PRINT K$:LOCATE 22,8:PRINT K$:LOCATE 24,8:PRINT K$:GOSUB 5070:RETURN 
4100 REM ZARI A6
4110 LOCATE 22,6:PRINT K$:LOCATE 24,6:PRINT K$:LOCATE 22,7:PRINT K$:LOCATE 24,7:PRINT K$:LOCATE 22,8:PRINT K$:LOCATE 24,8:PRINT K$:GOSUB 5070:RETURN
4500 REM SHOW B W
4510 IF PLIK=1 AND BANK1=0 THEN LOCATE 2,8:PRINT"B for Bank"
4520 IF PLIK=1 AND WATCH1=0 THEN LOCATE 2,10:PRINT"S for Watch"
4530 IF PLIK=2 AND G=1 THEN RETURN
4540 IF PLIK=2 AND BANK2=0 THEN LOCATE 28,8:PRINT"B for Bank"
4550 IF PLIK=2 AND WATCH2=0 THEN LOCATE 28,10:PRINT"S for Watch"
4560 RETURN
5000 SYMBOL AFTER 240
5001 SYMBOL 240,124,198,198,198,198,108,238:REM OMEGA
5002 SYMBOL 241,126,102,102,102,102,102,102:REM PI
5003 SYMBOL 242,124,96,96,96,96,96,96:REM GAMA
5004 SYMBOL 243,0,146,146,146,124,16,16,16:REM PSI
5005 SYMBOL 244,126,0,0,126,0,0,126,0:REM KSI
5006 SYMBOL 245,24,36,102,195,195,195,195,255:REM DELTA
5007 SYMBOL 246,24,36,102,195,195,195,195,0:REM LAMDA
5008 SYMBOL 247,16,124,214,214,214,124,16:REM PHI
5019 SYMBOL 255,0,0,60,126,60
5020 K$=CHR$(255)
5025 GAM$=CHR$(242):DEL$=CHR$(245):THI$=CHR$(181):LAM$=CHR$(246):KSI$=CHR$(244):PII$=CHR$(241):SIG$=CHR$(190):PHI$=CHR$(247):PSI$=CHR$(243):OME$=CHR$(240)
5030 RETURN
5040 REM SXEDIASI ZARIOU 1
5050 MOVE 239,270:DRAW 239,320:DRAW 289,320:DRAW 289,270:DRAW 239,270:RETURN
5060 REM SXEDIASI ZARIOU 2
5070 MOVE 335,270:DRAW 335,320:DRAW 385,320:DRAW 385,270:DRAW 335,270:RETURN
5100 REM SOUND ZARIOU 
5110 SOUND 1,2000,10,11,0,0,5:SOUND 1,0,5:SOUND 1,2000,8,5,0,0,5:SOUND 1,0,3:SOUND 1,2100,9,5,0,0,5
5190 RETURN
5200 REM SOUND ZARIOU KAKIAS
5210 SOUND 1,2000,10,5,0,0,5:SOUND 1,0,5:SOUND 1,2000,7,5,0,0,5
5290 RETURN
5300 REM GAME SOUND
5310 SOUND 1,568,15,15:SOUND 1,0,17:SOUND 1,426,21,15:SOUND 1,0,26:SOUND 1,426,18,15:SOUND 1,0,12:SOUND 1,568,18,15:SOUND 1,0,28:SOUND 1,426,18,15:SOUND 1,0,30
5320 SOUND 1,568,15,15:SOUND 1,0,17:SOUND 1,426,21,15:SOUND 1,0,26:SOUND 1,426,18,15:SOUND 1,0,12:SOUND 1,568,18,15:SOUND 1,0,28:SOUND 1,426,18,15:SOUND 1,0,60
5330 SOUND 1,213,15,15:SOUND 1,0,10:SOUND 1,201,15,15:SOUND 1,0,10:SOUND 1,169,15,15:SOUND 1,0,10:SOUND 1,159,15,15:SOUND 1,0,10:SOUND 1,142,15,15:SOUND 1,0,10
5340 SOUND 1,134,15,15:SOUND 1,0,10:SOUND 1,113,15,15:SOUND 1,0,10:SOUND 1,106,20,15:
5390 RETURN
5400 REM HXOS TELOUS
5450 SOUND 1,60,10,15:SOUND 1,63,10,15:SOUND 1,71,10,15:SOUND 1,80,10,15:SOUND 1,89,10,15:SOUND 1,95,10,15:SOUND 1,106,10,15:SOUND 1,119,10,15 
5460 SOUND 1,179,10,15:SOUND 1,190,10,15:SOUND 1,213,10,15:SOUND 1,239,10,15:SOUND 1,253,10,15:SOUND 1,284,10,15:SOUND 1,319,10,15:SOUND 1,358,10,15 
5470 SOUND 1,478,10,15:SOUND 1,506,10,15:SOUND 1,568,10,15:SOUND 1,638,10,15:SOUND 1,716,10,15:SOUND 1,758,10,15:SOUND 1,851,10,15:SOUND 1,956,50,15
5490 RETURN
5500 REM HXOS NIKIS
5510 SOUND 1,119,10,5:SOUND 1,80,28,5
5590 RETURN
6000 REM AMSTRAD CALCULATING BET
6005 TYX=RND:BET=TYX*Y/10:BET=CINT(BET)*10
6008  IF BET>Y*0.7 THEN GOTO 6005
6010 IF X<3000 AND Y>3000 THEN BET=X:GOTO 6020
6011 IF Y<3000 THEN BET=Y:GOTO 6020
6012 IF BET<400 THEN GOTO 6005
6015 IF BET>X THEN GOTO 6005
6020 RETURN
7000 REM ZARI EXO
7010 LOCATE 5,4:PRINT"DICE OUT!"  
7020 IF Z1=3 OR Z1=5 OR Z1=6 THEN KAKIA=1
7030 IF Z1=1 OR Z1=2 OR Z1=4 THEN KAKIA=2
7040 RETURN
7100 E$=INKEY$
7110 IF E$="" THEN GOTO 7100
7120 RETURN
7500 FOR DELAY=1 TO 500:NEXT DELAY:RETURN
7550 FOR DELAY=1 TO 1000:NEXT DELAY:RETURN
8000 REM SCORE FIX PLIK 1
8010 IF (Z1=1 OR Z1=2) AND (Z2=1 OR Z2=2) THEN X=X-BET:Y=Y+BET:NNB=2:WIN$=P2$:GOTO 8050
8020 IF Z1=4 AND Z2=4 THEN X=X-BET:Y=Y+BET:NNB=2:WIN$=P2$:GOTO 8050
8030 IF (Z1=5 OR Z1=6) AND (Z2=5 OR Z2=6) THEN X=X+BET:Y=Y-BET:WIN=1:NNB=2:WIN$=P1$:GOTO 8050
8040 IF Z1=3 AND Z2=3 THEN X=X+BET:Y=Y-BET:WIN=1:NNB=2:WIN$=P1$:GOTO 8050
8045 NNB=1
8050 RETURN
8100 REM SCORE FIX PLIK 2
8110 IF (Z1=1 OR Z1=2) AND (Z2=1 OR Z2=2) THEN Y=Y-BET:X=X+BET:NNB=2:WIN$=P1$:GOTO 8150
8120 IF Z1=4 AND Z2=4 THEN Y=Y-BET:X=X+BET:NNB=2:WIN$=P1$:GOTO 8150
8130 IF (Z1=5 OR Z1=6) AND (Z2=5 OR Z2=6) THEN Y=Y+BET:X=X-BET:WIN=1:NNB=2:WIN$=P2$:GOTO 8150
8140 IF Z1=3 AND Z2=3 THEN Y=Y+BET:X=X-BET:WIN=1:NNB=2:WIN$=P2$:GOTO 8150
8145 NNB=1
8150 RETURN
8400 PEN 1:INK 1,15:MODE 2:BCHANGE=1:GOSUB 9000:REM BANK
8410 IF PLIK=1 AND BANK1=1 THEN GOTO 8650
8420 IF PLIK=2 AND BANK2=1 THEN GOTO 8650
8430 IF PLIK=1 THEN LOCATE 2,17:PRINT P1$;", do you want a loan from the capitalist bank?":LOCATE 2,19:PRINT"Your house will be sold if you cannot pay."
8440 IF PLIK=2 THEN LOCATE 2,17:PRINT P2$;", do you want a loan from the capitalist bank?":LOCATE 2,19:PRINT"Your house will be sold if you cannot pay."
8450 LOCATE 2,21:PRINT"PRESS 1 TO ACCEPT LOAN OR 2 TO DENY LOAN"
8460 L$=INKEY$
8465 IF L$="1" AND PLIK=1 THEN HOS=2500+CINT(RND*100)*25:X=X+HOS:BANK1=1:LOCATE 15,24:PRINT"You took a loan of";HOS;"from the capitalist bank":GOSUB 7100:GOTO 8690
8470 IF L$="1" AND PLIK=2 THEN HOS=2500+CINT(RND*100)*25:Y=Y+HOS:BANK2=1:LOCATE 15,24:PRINT"You took a loan of";HOS;"from the capitalist bank":GOSUB 7100:GOTO 8690
8472 IF L$="2" THEN GOTO 8690
8480 GOTO 8460
8640 GOTO 8690
8650 LOCATE 2,18:PRINT"The capitalist bank will not offer you another loan":GOSUB 7100:GOTO 8690
8690 GOTO 260
8700 MODE 2:wCHANGE=1:GOSUB 9200:REM WATCH
8710 IF PLIK=1 AND WATCH1=1 THEN GOTO 8950
8720 IF PLIK=2 AND WATCH2=1 THEN GOTO 8950
8730 IF PLIK=1 THEN LOCATE 2,17:PRINT P1$;", do you want to sell your watch?":LOCATE 2,19:PRINT"Your watch is a present from your wife."
8740 IF PLIK=2 THEN LOCATE 2,17:PRINT P2$;", do you want to sell your watch?":LOCATE 2,19:PRINT"Your watch is a present from your wife."
8750 LOCATE 2,21:PRINT"PRESS 1 TO SELL WATCH OR 2 FOR NOT SELL"
8760 R$=INKEY$
8765 IF R$="1" AND PLIK=1 THEN WAP=1500+CINT(RND*50)*30:X=X+WAP:WATCH1=1:LOCATE 9,24:PRINT"You sold your watch for";WAP;",much less than your wife bought it.":GOSUB 7100: GOTO 8990
8770 IF R$="1" AND PLIK=2 THEN WAP=1500+CINT(RND*50)*30:Y=Y+WAP:WATCH2=1:LOCATE 9,24:PRINT"You sold your watch for";WAP;",much less than your wife bought it.":GOSUB 7100:GOTO 8990 
8772 IF R$="2" THEN GOTO 8990
8780 GOTO 8760
8950 LOCATE 2,18:PRINT"You have alredy sold your watch":GOSUB 7100:GOTO 8990
8990 GOTO 260
9000 REM DESIGN BANK
9010 MOVE 190,260:DRAW 390,260:DRAW 290,357:DRAW 190,260
9020 MOVE 190,260:DRAW 190,155:DRAW 390,155:DRAW 390,260
9025 MOVE 191,260:DRAW 191,155:MOVE 389,155:DRAW 389,260 
9030 MOVE 275,155:DRAW 275,210:DRAW 305,210:DRAW 305,155:PLOT 283,180:PLOT 284,180:PLOT 284,179:PLOT 283,179:PLOT 282,180:PLOT 282,179
9040 MOVE 210,210:DRAW 240,210:DRAW 240,240:DRAW 210,240:DRAW 210,210:MOVE 225,240:DRAW 225,210:MOVE 210,225:DRAW 240,225
9050 MOVE 370,210:DRAW 370,240:DRAW 340,240:DRAW 340,210:DRAW 370,210:MOVE 355,210:DRAW 355,240:MOVE 340,225:DRAW 370,225
9060 LOCATE 34,11:PRINT"$$$$$$$":LOCATE 27,14:PRINT "LOANS!":LOCATE 41,14:PRINT"CARDS!"
9070 MOVE 202,170:DRAW 258,170:DRAW 258,197:DRAW 202,197:DRAW 202,170:MOVE 370,170:DRAW 315,170:DRAW 315,197:DRAW 370,197:DRAW 370,170 
9100 LOCATE 33,6:PRINT"$$$$$$$$$":LOCATE 30,8:PRINT"CAPITALIST BANK":
9190 RETURN
9200 MODE 2:PEN 1:INK 1,15:BORDER 11:INK 0,0
9210 ORIGIN 300,342
9220 DEG
9225 MOVE 0,45
9230 FOR C=0 TO 360 STEP 10
9240 DRAW 45*SIN(C),45*COS(C)
9250 NEXT C
9260 ORIGIN 0,0
9270 LOCATE 37,2:PRINT"XII":LOCATE 34,4:PRINT"9":LOCATE 42,4:PRINT"3":LOCATE 38,6:PRINT"6"
9280 PLOT 300,341:PLOT 300,343:PLOT 299,341:PLOT 299,342:PLOT 299,343:PLOT 301,341:PLOT 301,342:PLOT 301,343:PLOT 300,342:DRAW 277,358:PLOT 301,342:DRAW 309,305
9290 PLOT 320,383:DRAW 320,400:PLOT 280,383:DRAW 280,400:PLOT 319,383:DRAW 319,400:PLOT 281,383:DRAW 281,400 
9300 PLOT 320,301:DRAW 320,185:PLOT 280,301:DRAW 280,185:DRAW 320,185:MOVE 281,301:DRAW 281,185:MOVE 319,301:DRAW 319,185
9310 MOVE 283,185:DRAW 285,160:DRAW 315,160:DRAW 317,185:MOVE 284,185:DRAW 286,160:MOVE 316,185:DRAW 314,160 
9320 MOVE 300,185:DRAW 300,170:MOVE 301,185:DRAW 301,170:MOVE 299,185:DRAW 299,170
9390 RETURN
9500 REM EXTRA ADD APO DIAGONISMO
9600 RETURN
9999 END